所以我从一个SO answer复制了这段代码:
grammar Mu;
parse
: block EOF
;
block
: stat*
;
stat
: assignment
| if_stat
| while_stat
| log
| OTHER {System.err.println("unknown char: " + $OTHER.text);}
;
assignment
: ID ASSIGN expr SCOL
;
if_stat
: IF condition_block (ELSE IF condition_block)* (ELSE stat_block)?
;
condition_block
: expr stat_block
;
stat_block
: OBRACE block CBRACE
| stat
;
while_stat
: WHILE expr stat_block
;
log
: LOG expr SCOL
;
expr
: expr POW<assoc=right> expr #powExpr
| MINUS expr #unaryMinusExpr
| NOT expr #notExpr
| expr op=(MULT | DIV | MOD) expr #multiplicationExpr
| expr op=(PLUS | MINUS) expr #additiveExpr
| expr op=(LTEQ | GTEQ | LT | GT) expr #relationalExpr
| expr op=(EQ | NEQ) expr #equalityExpr
| expr AND expr #andExpr
| expr OR expr #orExpr
| atom #atomExpr
;
atom
: OPAR expr CPAR #parExpr
| (INT | FLOAT) #numberAtom
| (TRUE | FALSE) #booleanAtom
| ID #idAtom
| STRING #stringAtom
| NIL #nilAtom
;
OR : '||';
AND : '&&';
EQ : '==';
NEQ : '!=';
GT : '>';
LT : '<';
GTEQ : '>=';
LTEQ : '<=';
PLUS : '+';
MINUS : '-';
MULT : '*';
DIV : '/';
MOD : '%';
POW : '^';
NOT : '!';
SCOL : ';';
ASSIGN : '=';
OPAR : '(';
CPAR : ')';
OBRACE : '{';
CBRACE : '}';
TRUE : 'true';
FALSE : 'false';
NIL : 'nil';
IF : 'if';
ELSE : 'else';
WHILE : 'while';
LOG : 'log';
ID
: [a-zA-Z_] [a-zA-Z_0-9]*
;
INT
: [0-9]+
;
FLOAT
: [0-9]+ '.' [0-9]*
| '.' [0-9]+
;
STRING
: '"' (~["\r\n] | '""')* '"'
;
COMMENT
: '#' ~[\r\n]* -> skip
;
SPACE
: [ \t\r\n] -> skip
;
OTHER
: .
;
我通过执行以下操作将代码编译成python:antlr4 -Dlanguage=Python3 Mu.g4
然后我尝试使用生成的python类运行python脚本:
import sys
from antlr4 import *
from MuLexer import MuLexer
from MuParser import MuParser
def main(argv):
input_stream = FileStream(argv[1])
lexer = MuLexer(input_stream)
stream = CommonTokenStream(lexer)
parser = MuParser(stream)
tree = parser.startRule()
if __name__ == '__main__':
main(sys.argv)
我这样称呼这个脚本:python3 script.py test.txt
然而,输出是:AttributeError: 'MuParser' object has no attribute 'startRule'
我不知道;我不明白为什么会发生这种情况,我所有的代码都是从教程中复制的
正如评论中已经提到的,在您的案例中,
startRule
应该替换为parse
。此方法对应于语法中的以下解析器规则:语法中的每一条规则都转换为一个可以调用的方法/函数。您通常希望使用在末尾有
EOF
(文件结尾)标记的规则:这样您可以强制解析器使用输入流中的所有标记要打印解析树的字符串表示形式,请添加以下内容:
相关问题 更多 >
编程相关推荐